【管理】WBS

WBSをエクセルで書くことが多いので、数式や書き方を記載。

  • 祝日の設定
    祝日は別紙「リスト」シートを作成し、A:Aに日付書式で管理する。
  • 終了日の自動設定(祝日除く)
    作業日数と開始日を入力すると祝日を除いた上で終了日を自動設定できるよう
    終了日に数式を設定する。

    ' 終了日の自動設定
    =IF(開始日セル="","",WORKDAY(開始日セル,ROUNDUP(作業日数セル,0)-1,リスト!祝日設定範囲))
    
  • 1ヶ月の日付の設定
    X月1日のセルに対して、YYYY/MM/DD形式でセルに入力し、
    書式をユーザ定義で「d」を設定する。
    X月2日のセルに対して、「X月1日のセル+1」を入力し、書式をユーザ定義で「d」を設定する。
    以降、繰り返しとなる。
  • 1ヶ月の曜日の自動設定
    曜日を入力したいセルに対して、数式を設定する。

    ' 曜日の自動設定
    ' aaa:「月」、「火」などの曜日1文字を表す
    ' aaaa:「月曜日」、「火曜日」などの曜日3文字を表す。
    =TEXT(X月1日のセル,"aaa")
    
  • 日ごとの書式設定
    祝日は灰色、タスクの作業期間中はオレンジ色で塗りつぶせるよう
    タスク行の日ごとのセルに数式を設定し、
    さらに条件付き書式を設定する。
    オレンジ色の条件付き書式4の優先順位を下げ、
    灰色の条件付き書式1~3の優先順位を上げ、
    「条件を満たす場合は停止」チェックをONにするところがミソ。

    ' タスク行の日ごとのセル
    ' 作業日が開始日と終了日の間(=作業期間中)の場合、1を設定している。
    =IF(OR(作業日数セル="",作業日数セル=0),"",IF(AND(作業日セル>=開始日セル,作業日セル<=終了日セル),1,""))
    
    ' 条件付き書式1
    ' 作業日が別紙「リスト」シートに設定した祝日範囲に含まれる場合、
    ' COUNTIFで1が返るため、条件がTUREとなる。
    ' この時、セルの塗りつぶしの色、フォント色を灰色にする。
    ' 「条件を満たす場合は停止」チェックをONにする。
    =COUNTIF(リスト!祝日設定範囲,作業日セル)=1
    
    ' 条件付き書式2
    ' 作業日が土曜日の場合、WEEKDAYで7が返るため、条件がTUREとなる。
    ' この時、セルの塗りつぶしの色、フォント色を灰色にする。
    ' 「条件を満たす場合は停止」チェックをONにする。
    =WEEKDAY(作業日セル)=7
    
    ' 条件付き書式3
    ' 作業日が日曜日の場合、WEEKDAYで1が返るため、条件がTUREとなる。
    ' この時、セルの塗りつぶしの色、フォント色を灰色にする。
    ' 「条件を満たす場合は停止」チェックをONにする。
    =WEEKDAY(作業日セル)=1
    
    ' 条件付き書式4
    ' 指定の値を含むセルだけを書式設定で
    ' 「セルの値」「次の値に等しい」「=1」を設定する。
    ' この時、セルの塗りつぶしの色、フォント色をオレンジ色にする。